再帰処理とは？指定したフォルダの全ての階層のフォルダ名・サブフォルダ名・ファイル名を取得（Excel VBA）

先日お話ししました

参照：指定したフォルダの全ての階層のフォルダ名・サブフォルダ名・ファイル名を取得（Excel VBA）

の中で、どのようにフォルダの処理を移動していったかをご説明いたします。

処理の大まかな流れは下記の通りです。

セルB3に、フォルダ・サブフォルダ・ファイル名を取得したいフォルダのパスを入力
セルB6に、一覧表を作りたいセル範囲の左上のセルアドレスを入力
<フォルダ・ファイル名一覧作成>ボタンをクリック
↓↓↓
セルB6に入力したアドレスに、ファイル・フォルダ一覧表が完成

使用したプロシージャはこちら。

'【変数】
Dim s_row As Long '開始行
Dim s_col As Long '開始列
Dim e_col As Long '終了列

Sub 指定したフォルダ内の全階層のフォルダ名とファイル名で一覧作成() ’・・・①-Start
    '【変数】
    'ファイル・シート関連関連
    Dim FSO As Object   'FileSystemObject
    Dim pt As String    '対象フォルダパス
    '行列関連
    Dim t_row As Long   '対象行
    Dim t_col As Long   '対象列

    Application.ScreenUpdating = False '画面表示の停止

    '■変数セット
    s_row = Range(Range("B6")).Row    '開始行
    s_col = Range(Range("B6")).Column '開始行
    t_row = s_row + 1                 '対象行
    t_col = s_col                     '対象列
    e_col = t_col                     '最終列

    '■FileSystemObjectのインスタンス化
    Set FSO = CreateObject("Scripting.FileSystemObject")

    '■対象フォルダパス（最後に「\」が無ければ「\」を付ける）
    If Right(pt, 1) = "\" Then
        pt = Range("B3")
    Else
        pt = Range("B3") & "\"
    End If

    '■対象フォルダの有無の確認
    If Not FSO.FolderExists(pt) Then
        MsgBox ("ご指定のフォルダは存在しません。")
        Exit Sub
    End If

    '■前回データのクリア
    Rows(s_row & ":" & Cells.Rows.Count).Clear

    '■再帰処理開始
    Call フォルダファイル名取得(FSO, pt, t_row, t_col)  ’・・・①-1

    '■列幅の調整
    Range(Columns(t_col), Columns(Columns.Count)).ColumnWidth = 3
    Range(Columns(e_col), Columns(e_col + 2)).EntireColumn.AutoFit

    '■サイズ、更新日時の罫線設定
    Range(Cells(s_row, e_col + 1), Cells(t_row - 1, e_col + 1)).BorderAround Weight:=xlHairline, LineStyle:=xlContinuous
    Range(Cells(s_row, t_col), Cells(t_row - 1, e_col + 2)).BorderAround LineStyle:=xlContinuous

    '■見出し設定
    Cells(s_row, s_col) = "フォルダ・ファイル名"
    Cells(s_row, e_col + 1) = "サイズ"
    Cells(s_row, e_col + 2) = "更新日時"
    Range(Cells(s_row, e_col + 1), Cells(s_row, e_col + 2)).HorizontalAlignment = xlCenter

    Application.Goto reference:=Range("A1"), scroll:=True
    Range(Range("B3"), Range("XFD2")).ClearFormats

    '■オブジェクトの解放
    Set FSO = Nothing

    Application.ScreenUpdating = False '画面表示の再開

End Sub  ’・・・①-End

Sub フォルダファイル名取得(FSO As Object, pt As String, t_row As Long, t_col As Long)  ’・・・②-Start

    '【変数】
    Dim s_fd As Object 'サブフォルダ
    Dim fl As Object 'ファイル
    Dim strSplit() As String

    '■最終列が増えた場合、サイズ列の前に1列追加
    If t_col > e_col Then
        Columns(t_col).Insert Shift:=xlToRight
        e_col = t_col
    End If

    '■サブフォルダの取得
    For Each s_fd In FSO.GetFolder(pt).SubFolders   ’・・・②-1-Start
        '□サブフォルダ名転記
        Cells(t_row, t_col) = s_fd.Name

        '□サブフォルダにハイパーリンクを設定
        ActiveSheet.Hyperlinks.Add _
            Anchor:=Cells(t_row, t_col), _
            Address:=s_fd.Path, _
            TextToDisplay:=s_fd.Name

        '□サブフォルダ名罫線設定
        Call 罫線(t_row, t_col)  ’・・・②-1-1

        t_row = t_row + 1

        '□再帰処理
        Call フォルダファイル名取得(FSO, s_fd.Path, t_row, t_col + 1)  ’・・・②-1-2
    Next s_fd  ’・・・②-1-End

    '■ファイル名の取得
    For Each fl In FSO.GetFolder(pt).Files  ’・・・②-2-Start

        '□ファイル名転記
        Cells(t_row, t_col) = fl.Name

        '■Excel・csvファイルはハイパーリンク設定
        strSplit = Split(fl.Path, ".")

        If UBound(strSplit) > 0 Then
            Select Case LCase(strSplit(UBound(strSplit)))
                Case "xls", "xlsx", "xlsm", "csv"
                    ActiveSheet.Hyperlinks.Add _
                        Anchor:=Cells(t_row, t_col), _
                        Address:=fl.Path, _
                        TextToDisplay:=fl.Name
            End Select
        End If

        '□ファイルサイズ・更新日時転記
        Cells(t_row, e_col + 1) = WorksheetFunction.RoundUp(fl.Size / 1024, 0)
        Cells(t_row, e_col + 1).NumberFormatLocal = "#,##0 ""KB"""
        Cells(t_row, e_col + 2) = fl.DateLastModified
        Cells(t_row, e_col + 2).NumberFormatLocal = "yyyy/mm/dd hh:mm:ss"

        '■ファイル名罫線
        Call 罫線(t_row, t_col)  ’・・・②-2-1

        t_row = t_row + 1
    Next fl   ’・・・②-2ーEnd

    '■オブジェクトの解放
    Set s_fd = Nothing
    Set fl = Nothing

End Sub  ’・・・②-End

Sub 罫線(t_row As Long, t_col As Long)  ’・・・③-Start

    '■左の罫線
    If t_col > s_col Then
        With Range(Cells(t_row, s_col), Cells(t_row, t_col - 1))
            .Borders(xlEdgeLeft).LineStyle = xlContinuous
            .Borders(xlInsideVertical).LineStyle = xlContinuous
        End With
    End If

    '■上の罫線
    With Range(Cells(t_row, t_col), Cells(t_row, e_col + 2))
        .Borders(xlEdgeLeft).LineStyle = xlContinuous
        .Borders(xlEdgeTop).LineStyle = xlContinuous
    End With

End Sub  ’・・・③-End

今回の処理で、変数「pt]に最初に指定しているのは「C:\VBA」というパスです。

その下に、第1階層→第2階層→第3階層というサブフォルダが入っています。

処理で指定しているのは「C:\VBA」だけなのに、なぜすべての階層のフォルダまで処理できたのでしょうか。

それらのことを可能にしているのが「再帰処理」なのです。

処理の要となるコードのみを下記に抜き出しました。

「再帰処理」とは、1つのプロシージャが終了していない途中で
「自分自身」を呼び出す処理のことです。

Sub 指定したフォルダ内の全階層のフォルダ名とファイル名で一覧作成()・・・①-Start
↓
Call フォルダファイル名取得(FSO, pt, t_row, t_col)・・・①-1
↓
Sub フォルダファイル名取得(FSO As Object, pt As String, t_row As Long, t_col As Long)・・・②-Start
↓
↓ 対象フォルダパス「pt」内のサブフォルダ、ファイルについて処理していきます。
↓
For Each s_fd In FSO.GetFolder(pt).SubFolders ・・・②-1-Start
↓
↓ 対象フォルダパス「pt」内のサブフォルダ「s_fd 」を順に処理します。
↓
Call 罫線(t_row, t_col)・・・②-1-1
↓
Sub 罫線(t_row As Long, t_col As Long)・・・③-Start
↓
End Sub・・・③-End
↓
Call フォルダファイル名取得(FSO,s_fd.Path, t_row, t_col + 1)・・・②-1-2
↓
↓ サブフォルダのパス変数「s_fd.Path」→「pt」として渡し、②-Startの処理を、
↓ サブフォルダが無くなるまで繰り返します。
↓ これが、1つのプロシージャが終了していない途中で「自分自身」を呼び出す「再帰処理」です。
↓
Sub フォルダファイル名取得(FSO As Object, pt As String, t_row As Long, t_col As Long)・・・②-Start
・
・ サブフォルダが無くなるまで ②-Start～②-1-2を繰り返し処理
・
↓ サブフォルダが無くなったら「②-1-Start」の処理に入らず、次の処理に移ります。
↓
For Each fl In FSO.GetFolder(pt).Files・・・②-2-Start
・
・

フォルダ・ファイルの処理順は下記の通りです。
この順に表にフォルダ名・ファイル名が記載されていきます。

【参考】

■■■スポンサーリンク■■■