指定したフォルダ内から「特定の文字を含まないファイル名」を取得（Excel VBA）

【本日のミッション】

Excel VBAにて、指定したフォルダ内から「特定の文字を含まないファイル名」を取得し、Excelのシートに書き出せ

「特定の文字を含む」ってよく見かけるけど、「特手の文字を含まない」条件にするには、ちょっと工夫が必要です。

1 ミッションの概要
2 ファイルの準備とプロシージャ
3 「特定の文字を含まない」の幅を広げる
4 Not A Like B
5 【参考】

ミッションの概要

今回指定フォルダにするのはこちらです。

このフォルダに入っている、「不可」の文字を含まないファイル名を、Excelのシートに書き出すというミッションです。

ファイルの準備とプロシージャ

Excelマクロ有効ブック（.xlsm）のファイルを新規作成します。

そのファイルのシートに下記の通り、

フォルダのパスを入力するセル（A3）
含まれないようにする文字を指定するセル（A6）
取得したファイル名を書き出すセル（A9：9行目1列目）を準備します。

フォルダパスには、ファイル名を取得したいフォルダのフルパスを入力します。

このシートをアクティブにした状態で、Alt＋F11でVsual Basic Editerを起動します。

［挿入］－［標準モジュール］で新規モジュールを作成し、下記の通りコードを記入します。

■■■スポンサーリンク■■■

Sub 指定したフォルダ内から特定の文字を含まないファイル名のみを取得()

    '【変数】
    Dim ws As Worksheet '処理対象シート
    Dim fn As String    'ファイル名
    Dim t_row As Long   '処理ターゲット行
    Dim pt As String    '処理対象フォルダパス
    Dim NG_Word As String   'この文字が含まれないファイル名を取得

    '■変数セット
    Set ws = ActiveSheet        '変数ws=アクティブシートをセット
    pt = ws.Range("A3")         '変数ptにセルA3のパスをセット
    NG_Word = "*" & ws.Range("A6") & "*"    'この文字が含まれないファイル名を取得
    t_row = 9                   '変数t_rowにファイル名を書き出す初めのセルの行番号をセット

    fn = Dir(pt & "\*.*") '変数fnに1個目のファイル名を格納

    Do While fn <> ""          'fnが空欄になるまでDo While内の処理を続ける
    
        If Not fn Like NG_Word Then 'NG_Wordが含まれないファイル名のみ処理を続ける
            ws.Cells(t_row, 1) = fn 'Cells(t_row, 1)にファイル名を書き出し
            t_row = t_row + 1       'ファイル名を書き出すセルの行番号+1（一つ下の行番号）
        End If
        
        fn = Dir()             '変数fnに次のファイル名を格納（ファイルが無い場合は空欄になる）
    Loop

End Sub

記入したプロシージャ（Sub～End Subまで）のどこかにカーソルを置いてF5キーをクリックしてください。

Excelのシートを見てください。

ファイル名を書き出すセルは9行目の1列目から下に順に書き出すようなコードにしています。

取捨選択フォルダに入っている「不可」の文字を含まないファイル名が書き出されました♪

「特定の文字を含まない」の幅を広げる

特定の文字は、ws.Range(“A6”) の「不可」という文字列にしています。

更に「～不可」「不可～」「～不可～」全てのパターンを含まないように、前後に”＊”を付けるようにしています。

参考：ワイルドカードとは。使い方いろいろ。（Excel）

NG_Word = "*" & ws.Range("A6") & "*"

Not A Like B

今回のように、「指定した文字を含まない」を条件にする場合は、

Not A Like B
「AがBのパターンとマッチしない場合はTrueを返す」

というLike演算子を使用します。

If Not fn Like NG_Word Then

fn（ファイル名）が「NG_Word（＊不可＊）」のパターンとマッチしない場合はTrueを返します。

【参考】

■■■スポンサーリンク■■■