リストボックスの値リストで選択している複数のデータを全て取得する（Excel VBA)Excel

【本日のミッション】

リストボックスの値リストで選択している複数のデータを全て取得せよ。

1 ミッションの概要
2 ユーザーフォームにコマンドボタンを追加する
3 値リストで複数選択しているデータを取得するコードを、コマンドボタンに設定
4 ユーザーフォームを表示して動作を確認
5 Selectedプロパティ
- 5.1 リストボックスで指定した行の選択状況を調べる
- 5.2 リストボックスのデータの選択・選択解除
6 ListCount プロパティ
7 Listプロパティ
- 7.1 値リストで指定した「行」「列」のデータを取得
- 7.2 データが選択されていないときの値
8 【参考】

ミッションの概要

リストボックスの値リストで選択している複数のデータを全て取得せよ、というのが今回のミッションです。

リストボックスの値リストで、データを複数選択できるようにする設定（Excel VBA) で作成したリストボックスの下に

値リストで複数選択しているデータを取得するコマンドボタン

を作り、複数選択しているデータをダイアログ表示します。

ユーザーフォームにコマンドボタンを追加する

ユーザーフォームを表示させる

画面左のプロジェクトエクスプローラーから、ユーザーフォームをダブルクリックして表示させます。

ツールボックスを表示させる

ツールボックスを、下記方法で表示させます。

ツールボックスを表示する方法1

[表示]－[ツールボックス]

ツールボックスを表示する方法2

標準ツールバーの［ツールボックス］ボタンをクリックします。

標準ツールバーが表示されていない場合は、［表示］－[ツールバー］－[標準］で表示されます。

■■■スポンサーリンク■■■

ユーザーフォームにコマンドボタンを配置する

ツールボックスから「コマンドボタン」をクリックします。

リストボックスの下にコマンドボタンを作成します。
リストボックス・コマンドボタンの位置は、程よく調整します。

左のプロパティウインドウで確認すると、コマンドボタンのオブジェクト名が「CommandButton1」ということが確認できます。

この「CommandButton1」というオブジェクト名を「データを取得」、Captionも「データを取得」に変更します。Captionを変更することで、ボタンの表示名が「CommandButton1」から「データを取得」に変更されます。

値リストで複数選択しているデータを取得するコードを、コマンドボタンに設定

［データを取得］ボタンをダブルクリックすると、コードウィンドウが表示され、下記コードが追加されています。

「Private Sub 〇〇〇_Click()」に書いた処理は、〇〇〇をクリックした時に行われます。

Private Sub データを取得_Click()

End Sub

ここに［データを取得］ボタンをクリックした時の動作を追加します。

「ListBox1」でデータが選択されていない時のダイアログ表示
「ListBox1」で選択しているデータをダイアログ表示

Private Sub UserForm_Initialize() 
    Dim ary_d                  'リストに設定するデータ用配列 
    ary_d = Worksheets("サザエさん").Range("A2:D9")
    With ListBox1
        .MultiSelect = fmMultiSelectExtended '複数選択
        .ColumnCount = 4                     '表示列数
        .ColumnWidths = "40;45;40;40"        '列幅
        .List = ary_d                        '参照範囲
    End With
End Sub

Private Sub データを取得_Click()
    Dim i As Long         'カウンター
    Dim namae As String   '名前
    For i = 0 To ListBox1.ListCount - 1
        'データが選択されている場合
        If ListBox1.Selected(i) = True Then
            '選択データの取得
            namae = namae & ListBox1.List(i, 1) & vbCrLf
        End If
    Next i
    '選択データの表示
    If namae = "" Then
        MsgBox "何も選択されていません。"
    Else
        MsgBox namae
    End If
End Sub

■■■スポンサーリンク■■■

ユーザーフォームを表示して動作を確認

このコード内にカーソルを置いたまま、［F5］キーをクリックすると（ユーザーフォームの実行）ユーザーフォームが表示されます。

配列に入れるデータの参照先にシート名が含まれていないと、アクティブになっているシートのセルデータが使用されるので注意が必要です。シート名を参照先に含めていない場合は、参照データのシートをアクティブにしてからマクロを実行してください。

ary_d = Worksheets("サザエさん").Range("A2:D9")

「配列」参照：セル範囲を一気に変数（配列）に入れる～バリアント型(Variant)変数を配列として使用する～（Excel VBA）

メイン画面が表示されます。

値リストから複数のデータを選択し、<データを取得>ボタンをクリックします。
選択しているデータ全てがダイアログ表示されます。

今回は、［閉じる］ボタンを付けていないため［×］ボタンでユーザーフォームを閉じます。

■■■スポンサーリンク■■■

Selectedプロパティ

Selectedプロパティには「リストボックスで指定した行の選択状況を調べる」「リストボックスのデータの選択・選択解除」の機能があります。

リストボックスで指定した行の選択状況を調べる

リストボックスで指定した行が、選択されているか、選択されていないかを調べます。

リストオブジェクト.Selected(選択状況を調べたい行位置)

「選択状況を調べたい行位置」は値リストの一番上の項目を「0」として数えます。
選択されている行は「True」、選択されていない行は「False」を返します。

値	内容
True	リストボックスの項目は選択されています。
False	リストボックスの項目は選択されていません。

リストボックスのデータの選択・選択解除

値リストの行を選択したり、選択解除したりします。

リストオブジェクト.Selected(選択状況を設定する行位置)=選択状況

「選択状況を設定する行位置」は値リストの一番上の項目を「0」として数えます。
選択状況に「True」を指定すると選択し、「False」を指定すると選択解除します。

ListBox1.Selected(3) = True

ListBox1.Selected(3) = False

選択状況	内容
True	指定した行位置の項目を選択します。
False	指定した行位置の項目の選択を解除します。

ListCount プロパティ

リストボックスに設定済の値リストの項目数を取得します。

ListBox1.ListCount

値リストの一番上を「1」件目としてカウントするので、下記リストの項目数は「8」件になります。

Listプロパティ

値リストで指定した「行」「列」のデータを取得

Listプロパティと言えば、リストボックスに値リストを設定するプロパティなのでは？
（参照：リストボックスにListプロパティを使って配列に格納した複数列のセルデータを値リストとして設定（Excel VBA)）

その他にListプロパティには、設定した値リストから「行」「列」を指定してデータを取得する機能もあります。

リストボックスオブジェクト.List（値を取得したい行,値を取得したい列）

値を取得したい行：値リストの1行目を「0」として数えます。
値を取得したい列：値リストの1列目を「0」として数えます。

値を取得したい行も値を取得したい列も、省略した場合は「0」が指定されます。

今回は「値を取得したい行」に「ListBox1.ListIndex」を指定しています。
ListIndexプロパティは、リストボックスで選択しているデータの行位置（インデックス値）を取得します。インデックス値は、1行目を「0」として数えます。
（参照：リストボックスで選択しているデータがリストの上から何番目（インデックス値）かを取得（Excel VBA)）

値を取得したい行=3
値を取得したい列=1

と指定しているので、結果は「マスオ」さんになります。

データが選択されていないときの値

Listプロパティでデータを取得する際、値リストから何も選択されていないと下記エラーが表示されます。

実行時エラー '381':
Listプロパティの値を取得できません。プロパティの配列のインデックスが
無効です。

値リストからデータが選択されていない場合、「ListBox1.ListIndex」は「-1」を返します。値リストの行に「-1」は無いのでエラーになります。

下記コードで、エラー回避をする必要があります。

If ListBox1.ListIndex = -1 Then
    MsgBox "データが選択されていません。"
Else
    MsgBox ListBox1.List(ListBox1.ListIndex, 1)
End If

【参考】

■■■スポンサーリンク■■■