エクセル VBA 実行時エラー ” 取り込み先の範囲は、クエリテーブルが作成された同じワークシートにありません。を解決

【本日のミッション】

Excel VBA QueryTables.Addメソッドで「実行時エラー ‘-2147024809(80070057)’
取り込み先の範囲は、クエリテーブルが作成された同じワークシートにありません。」が出た原因をつきとめよ。

1 ミッションの概要
2 プロシージャ
3 QueryTables.Addメソッドクエリテーブルを作るシート＝取込先シートでないとエラーが出る
4 【参考】

ミッションの概要

Excel VBA QueryTables.Addメソッドで「実行時エラー ‘-2147024809(80070057)’
取り込み先の範囲は、クエリテーブルが作成された同じワークシートにありません。」が出た原因をつきとめよ、というのが今回のミッションです。

下記参照ページのコードを使用します。コードの詳細は、下記ページをご参照ください。

参照：Excel VBAダイアログボックスで選択したcsvをQueryTablesで取込（「,」「”」ゼロ落ち・日付変換対応）

■■■スポンサーリンク■■■

プロシージャ

赤字でコメントブロックしている部分が、エラーになった箇所です。
その上の青字部分が、エラーを出ないようにしたコードです。

 Sub CSV取込4()

    '【変数】
    Dim fn As Variant       '取込ファイル名
    Dim ws As Worksheet     'データ取込用シート（このブックのsheet1）
    Dim qt As QueryTable    'QueryTableオブジェクト
    
    '■変数セット
    Set ws = ThisWorkbook.Worksheets("Sheet1")  'データ取込用シート（このブックのsheet1）
    '■ファイルの選択
    fn = Application.GetOpenFilename(FileFilter:="CSVファイル(*.csv),*.csv")
    
    '■ファイル選択の確認
    If fn = False Then
        Exit Sub           'ファイル選択されていなかったら終了
    End If
    
    '■QueryTableオブジェクトを追加
    Set qt = ws.QueryTables.Add(Connection:="text;" & fn, Destination:=ws.Range("A1"))            '←エラーの出ないコード
    ’Set qt = ws.QueryTables.Add(Connection:="text;" & fn, Destination:=Activesheet.Range("A1"))  ’←エラーの出るコード
    
    '■プロパティを指定→csv取込→接続解除
    With qt
        .TextFilePlatform = 932                             '文字コードを指定 Shift_Jis
        .TextFileCommaDelimiter = True                      'カンマ区切り
        .TextFileColumnDataTypes = Array(2, 1, 1, 2, 1, 1)  'データ型
        .Refresh BackgroundQuery:=False                     'CSVデータをワークシートに取込
        .Delete                                             'CSVファイルとの接続を解除
    End With
End Sub

QueryTables.Addメソッドクエリテーブルを作るシート＝取込先シートでないとエラーが出る

「QueryTables」は、ワークシートにQueryTableオブジェクトを追加するメソッドです。

取込先のワークシート.QueryTables.Add(Connection, Destination[, Sql])

引数名	説明	省略
Connection	取り込むデータベースの種類と、取り込むデータのバスを指定します。CSVを取り込む場合は必ず「text;」から指定し、その後にデータのパスを指定します。	×
Destination	QueryTablesに取り込んだcsvを、どのワークシートのどのセル番地に取込ませるか指定します。取込先ワークシートは、クエリテーブルを作るシートと同じでないとエラーが出ます。「実行時エラー ‘-2147024809(80070057)’ 取り込み先の範囲は、クエリテーブルが作成された同じワークシートにありません。」	×
Sql	ODBC データソースで実行される SQL クエリ文字列。	〇

引数名

説明

省略

Connection

取り込むデータベースの種類と、取り込むデータのバスを指定します。CSVを取り込む場合は必ず「text;」から指定し、その後にデータのパスを指定します。

Destination

QueryTablesに取り込んだcsvを、どのワークシートのどのセル番地に取込ませるか指定します。取込先ワークシートは、クエリテーブルを作るシートと同じでないとエラーが出ます。

「実行時エラー ‘-2147024809(80070057)’
取り込み先の範囲は、クエリテーブルが作成された同じワークシートにありません。」

Sql

ODBC データソースで実行される SQL クエリ文字列。

〇

実行時エラー「取り込み先の範囲は、クエリテーブルが作成された同じワークシートにありません。」とは、QueryTablesが作られるシートと、csvを取込ませるシートが異なる場合に表示されるエラーです。

QueryTablesが作られるシートと、csvを取込ませるシートが同じであれば、エラーは出ません。

ws.QueryTables.Add(Connection:="text;" & fn, Destination:=ws.Range("A1"))

■■■スポンサーリンク■■■

【参考】

■■■スポンサーリンク■■■

ミッションの概要

プロシージャ

QueryTables.Addメソッド クエリテーブルを作るシート＝取込先シート でないとエラーが出る

【参考】

QueryTables.Addメソッドクエリテーブルを作るシート＝取込先シートでないとエラーが出る