Excel は〇〇が SYLK ファイルであることを確認しましたが、読み込むことができません。のエラーを回避（VBA）

【本日のミッション】

Excel VBA で、csvファイルを開く時に「Excel は ‘購入履歴.csv’ が SYLK ファイルであることを確認しましたが、読み込むことができません。ファイルにエラーが含まれるか、SYLK ファイル形式でない可能性があります。異なるファイル形式でそのファイルを開くには、[OK]をクリックしてください。」というエラーが出た。このエラーを回避せよ。

1 ミッションの概要
2 プロシージャ
3 SYLKファイルとは
4 「Excel は ‘〇〇〇.csv’ が SYLK ファイルであることを確認しましたが、読み込むことができません。ファイルにエラーが含まれるか、SYLK ファイル形式でない可能性があります。異なるファイル形式でそのファイルを開くには、[OK]をクリックしてください。」エラーの原因
5 Application.DisplayAlerts プロパティ
6 【参考】

ミッションの概要

問題となったのは、こんなcsvファイルです。Excelで開こうとするVBA（下記ページ参照）の途中でエラーが表示されました。

参考：Excel VBAダイアログボックスで選択したcsvファイルをエクセルブックとして開いて取込（「,」「”」対応）

↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓

Excel は〇〇が SYLK ファイルであることを確認しましたが、読み込むことができません。のエラーを回避（VBA）

<OK>ボタンをクリックしたら、ファイルは開いたのですが・・・
↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓

できることなら、エラー画面は出てきて欲しくないですよね。

■■■スポンサーリンク■■■

プロシージャ

今回エラーを回避するために、下記ページのコードに赤字部分を追加しております。

参考：Excel VBAダイアログボックスで選択したcsvファイルをエクセルブックとして開いて取込（「,」「”」対応）

Sub CSV取込1()

    '【変数】
    Dim fn As Variant       '取込ファイル名
    Dim ws As Worksheet     'データ貼付用シート（このブックのsheet1）
    Dim ws_d As Worksheet   'データ取込シート
    Dim ary_d As Variant    'データ取込用配列
    Dim e_row_d As Long     'データ取込シート 最終行
    Dim e_col_d As Long     'データ取込シート 最終列
    
    '■画面更新STOP
    Application.ScreenUpdating = False
    
    '■変数セット
    Set ws = ThisWorkbook.Worksheets("Sheet1")  'データ貼付用シート（このブックのsheet1）

    '■ファイルの選択
    fn = Application.GetOpenFilename(FileFilter:="CSVファイル(*.csv),*.csv")
    
    '■ファイル選択の確認
    If fn = False Then
        Exit Sub        'ファイル選択されていなかったら終了
    End If
  
    '■選択したファイルを開く
    Application.DisplayAlerts = False
    Workbooks.Open Filename:=fn
    Application.DisplayAlerts = True
    Set ws_d = ActiveSheet          'データ取込シート
    
    '■最終行・最終列の取得
    e_row_d = ws_d.Cells(ws_d.Rows.Count, 1).End(xlUp).Row              'データ取込シート 最終行
    e_col_d = ws_d.Cells(3, ws_d.Columns.Count).End(xlToLeft).Column    'データ取込シート 最終列
    
    '■データ取込シート→配列ary_d
    ary_d = ws_d.Range(ws_d.Cells(1, 1), ws_d.Cells(e_row_d, e_col_d))
    
    '■配列ary_d→データ貼付用シート（このブックのsheet1）
    ws.Range(ws.Cells(1, 1), ws.Cells(e_row_d, e_col_d)) = ary_d
    
    '■ファイルを閉じる
    ActiveWorkbook.Close SaveChanges:=False
    
    '■画面更新STOP解除
    Application.ScreenUpdating = True
End Sub

SYLKファイルとは

SYLKファイルは、表計算ソフトの表データなどを格納することができる、データ交換フォーマットのひとつで、ファイルの最初の行は「ID」から始まります。

「Excel は ‘〇〇〇.csv’ が SYLK ファイルであることを確認しましたが、読み込むことができません。ファイルにエラーが含まれるか、SYLK ファイル形式でない可能性があります。異なるファイル形式でそのファイルを開くには、[OK]をクリックしてください。」エラーの原因

今回開いたcsvファイルは、先頭の文字が「ID」です。

Excelはファイルの先頭文字が「ID」から始まっているということで、このファイルは「SYLKファイルだ！」と誤認識してエラーを表示させています。

↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓

■■■スポンサーリンク■■■

Application.DisplayAlerts プロパティ

このプロパティを「False」にした場合、マクロの実行中に特定の警告やメッセージを表示しません。

Application.DisplayAlerts = False

今回はエラーの元となる「Workbooks.Open Filename:=fn」の前に、このコードを追加しています。エラー回避後は「True」に戻しておきます。

Application.DisplayAlerts = False
Workbooks.Open Filename:=fn
Application.DisplayAlerts = True

【参考】

■■■スポンサーリンク■■■