リストボックス TextプロパティとValueプロパティの違い（Excel VBA）Excel

【本日のミッション】

リストボックスで値を取得するプロパティに「Textプロパティ」と「Valueプロパティ」の2つがあるが、違いを検証せよ。

1 ミッションの概要
2 列指定するプロパティが異なる
- 2.1 TextプロパティとTextColumnプロパティ
- 2.2 ValueプロパティとBoundColumnプロパティ
3 リストボックスで何も選択していないときの結果が異なる
- 3.1 Textプロパティ
- 3.2 Valueプロパティ
4 【参考】

ミッションの概要

リストボックスで値を取得する「Textプロパティ」と「Valueプロパティ」の違いを検証するのが、今回のミッションです。

今回のミッションは、リストボックスにListプロパティを使って配列に格納した複数列のセルデータを値リストとして設定（Excel VBA)で作成したリストボックスにコマンドボタン2つを追加し、両プロパティの結果の違いを検証します。

コマンドボタンの設置方法はリストボックス複数列の値リストで選択しているデータを、列指定してListプロパティで取得（Excel VBA)をご参照ください。

↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓

↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓

列指定するプロパティが異なる

Textプロパティで取得する列は、TextColumnプロパティで指定します。
Valueプロパティで取得する列は、BoundColumnプロパティで指定します。

Private Sub UserForm_Initialize()
    Dim ary_d 'リストに設定するデータ用配列
    ary_d = Worksheets("サザエさん").Range("A2:D9")
    With ListBox1
        .ColumnCount = 4               '表示列数
        .TextColumn = 2                'Textプロパティで取得する値
        .BoundColumn = 1               'Valueプロパティで取得する値の列
        .ColumnWidths = "40;45;40;40"  '列幅
        .List = ary_d                  '参照範囲
    End With
End Sub

Private Sub Textプロパティを取得_Click()
    If ListBox1.Text = "" Then
        MsgBox "データが選択されていません。"
    Else
        MsgBox ListBox1.Text 
    End If
End Sub

Private Sub Valueプロパティを取得_Click()
    If IsNull(ListBox1.Value) Then
        MsgBox "データが選択されていません。"
    Else
        MsgBox ListBox1.Value
    End If
End Sub

■■■スポンサーリンク■■■

TextプロパティとTextColumnプロパティ

TextColumnプロパティで指定した列は、Textプロパティで値取得される列になります。規定値は1列目です。

ListBox1.TextColumn = 2
↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓
MsgBox ListBox1.Text

上記コードでは、TextColumnプロパティで2列目の「名前」を指定しています。これをTextプロパティで取得すると「マスオ」がダイアログ表示されます。

参照：リストボックス複数列の値リストで選択しているデータを、列指定してTextプロパティで取得（Excel VBA)

ValueプロパティとBoundColumnプロパティ

BoundColumnプロパティで指定した列は、Valueプロパティで値取得される列になります。規定値は1列目です。

ListBox1.BoundColumn = 1
↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓↓
MsgBox ListBox1.Value

上記コードでは、BoundColumnプロパティで1列目の「ID」を指定しています。これをValueプロパティで取得すると「ID04」がダイアログ表示されます。

参照：リストボックス複数列の値リストで選択しているデータを、列指定してValueプロパティで取得（Excel VBA)

リストボックスで何も選択していないときの結果が異なる

Textプロパティは空欄「””」を返し、Valueプロパティはエラーになります。

Textプロパティ

Textプロパティでは、データが選択されていない時 空欄「””」が表示されます。
下記コードで、空欄表示を回避をする必要があります。

If ListBox1.Text = "" Then
    MsgBox "データが選択されていません。"
Else
    MsgBox ListBox1.Text 
End

↓↓↓↓↓↓↓↓↓

Valueプロパティ

Valueプロパティでは下記エラーが表示されてしまいます。

実行時エラー '94':
Nullの使い方が不正です。

下記コードで、エラー回避をする必要があります。

If IsNull(ListBox1.Value) Then
    MsgBox "データが選択されていません。"
Else
    MsgBox ListBox1.Value
End if

↓↓↓↓↓↓↓↓↓

【参考】

■■■スポンサーリンク■■■